full screen gui

 

Here an example to switch in/out full screen with F11

version 0.2

; https://www.autoitscript.com/forum/topic/210078-full-screen-gui/?do=findComment&comment=1516762

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region (=== GUI generated by GuiBuilderPlus 1.0.0-beta4 ===)
Global $hGUI = GUICreate("MyGUI", 400, 350, 760, 365, -1, -1)
Global $idFullScreen = GUICtrlCreateDummy()
#EndRegion (=== GUI generated by GuiBuilderPlus 1.0.0-beta4 ===)

_main()

;------------------------------------------------------------------------------
; Title...........: _main
; Description.....: run the main program loop
;------------------------------------------------------------------------------
Func _main()
    GUISetState(@SW_SHOW)

    Local $aAccelKeys[1][2] = [["{F11}", $idFullScreen]]
    GUISetAccelerators($aAccelKeys)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $idFullScreen
                _FullScreen()

            Case Else

                ;
        EndSwitch

        Sleep(10)
    WEnd
EndFunc   ;==>_main
;------------------------------------------------------------------------------
Func _FullScreen()
    Local Static $aWPos, $aGUIStyle = GUIGetStyle($hGUI), $iFullScreen = 0

    If $iFullScreen = 0 Then
        $aWPos = WinGetPos($hGUI)
        WinMove($hGUI, "", 0, 0, @DesktopWidth, @DesktopHeight)
        GUISetStyle(BitOR($WS_POPUP, $WS_EX_TOPMOST), -1)
        $iFullScreen = 1
    Else
        WinMove($hGUI, "", $aWPos[0], $aWPos[1], $aWPos[2], $aWPos[3])
        GUISetStyle($aGUIStyle[0], $aGUIStyle[1])
        $iFullScreen = 0
    EndIf
EndFunc   ;==>_FullScreen
;------------------------------------------------------------------------------

Please, leave your comments and experiences here.

Thanks !